求一个威纶通触摸屏断电保存PLC数据的案例程序

qq263946146 · 2019-12-2 12:16:05

HMI:MT6070IH
PLC:松下FPX-C40T
如何用触摸屏断电保存PLC数据，并且开机后自动传输过去，修改时也可以传输到PLC上面。
谢谢。

回答：
用触发式资料传输或者定时式资料传输将PLC数据发送到触摸屏掉电保持的RW地址。
然后宏指令用GetDATA函数读取RW地址数据，用SetData发送到PLC。
开机执行或者每次改了数据后都执行。
当然如果宏指令熟悉的话，可以直接全部用宏指令来实现，
在什么时候需要传输，用什么方式触发宏就好。
这里给你编写的一个实例来实现一下功能。
例程界面如下：

程序共设计有两组参数供选择使用，通过组合框可以选择使用哪组参数，
每组参数会在编辑框中显示出来，如图中上第一行编辑框。
一组参数为触摸屏配方寄存器RW0---RW4,
二组参数为触摸屏配方寄存器RW5---RW5,
组合框通过索引寄存器LW9200来选择使用哪组，并显示在第一行编辑框中。

选择后会触发LB0,设置LB0为ON.
如下图，具体设置可以在例程中，打开此元件属性时查看。

至于LB0如何触发宏指令，可以通过PLC控制元件，间接实现。
如下图为此元件属性的设置。

触发的宏指令代码如下：
macro_command main()
short nValue[5]
short nIndex=0
bool b=false
//LB0由组合框置ON,未得电表示为屏刚上电初始化
GetData(b, "Local HMI", LB, 0, 1)
if b == false then
GetData(nIndex, "Local HMI", RW, 100, 1)
SetData(nIndex, "Local HMI", LW, 9200, 1)
//
GetData(nValue[0], "Local HMI", RW, nIndex, 5)
SetData(nValue[0], "Panasonic FP/KW", DT, 0, 5)
return
end if

//LB0由组合框置ON，触发保存
GetData(nIndex, "Local HMI", LW, 9200, 1)
SetData(nIndex, "Local HMI", RW, 100, 1)
//
GetData(nValue[0], "Local HMI", RW, nIndex, 5)
SetData(nValue[0], "Panasonic FP/KW", DT, 0, 5)
///复位
b=false
SetData(b, "Local HMI", LB, 0, 1)
end macro_command

上面的宏代码实现了在组合框使用时，
1.保存索引到配方寄存器.
2.从配方寄存器读取对应组别参数。
3.将读取参数传输到PLC.
4.复位宏触发位LB0等功能。
5.同时勾选了上电时HMI执行一次，在上电时初始化组合框与对应数据。
也就是会将断电前保存的组别参数自动传输到PLC。

然后就是对编辑框的处理，在编辑好数据后，也要将数据传输到PLC。
这里就要用到数值输入元件的通知功能，相关设置如下。
更多设置可以下载例程查看。

图中我们也使用了索引寄存器LW9200,这样组合框选择不同组别时，此元件也会对应显示数据。
也设置了在数值写入后将LB1设置为ON，
这样LB1就可以用到触发宏指令，具体如何触发，两样也是通过PLC控制元件。
与上边用到的通过LB0触发宏一样，就不截图了。

宏指令如下：
macro_command main()
short nIndex=0
//索引已由另一宏储存在RW100
//GetData(nIndex, "Local HMI", LW, 9200, 1)
GetData(nIndex, "Local HMI", RW, 100, 1)
//
short nValue[5]
GetData(nValue[0], "Local HMI", RW, nIndex, 5)
SetData(nValue[0], "Panasonic FP/KW", DT, 0, 5)
//LB1由编辑框设为ON,复位.
bool b = false
SetData(b, "Local HMI", LB, 1, 1)
end macro_command

宏代码里先获取索引值，根据索引值读取对应配方寄存器数据并传输到PLC寄存器。
同时也负责将触发条件LB1复位。
PLC寄存器的变化，例程也在界面显示出来，如第二行编辑框显示。
效果如下图：

这样就实现了触摸屏断电保存PLC数据，
开机后自动传输数据到PLC，
修改时也传输到PLC的功能。
更多细节可以下载例程学习。

请点击此处下载

请先注册会员后在进行下载

已注册会员，请先登录后下载