工控编程吧

标题: 工业视觉halcon boundary函数介绍 [打印本页]

作者: qq263946146 时间: 2019-6-1 15:55
标题: 工业视觉halcon boundary函数介绍
boundary(Region : RegionBorder : BoundaryType : )
boundary通过形态学运算计算区域的边界。
参数BoundaryType 决定要计算的边界层类型:
'inner', 'inner_filled' 或是'outer'

boundary计算每个输入区域的轮廓。
结果区域只由输入区域的最小边界组成。
如果将BoundaryType设置为‘inner’，轮廓线在原始区域内，
如果将其设置为‘outer’，则轮廓线在原始区域外为一个像素。
如果将边界层类型设置为“inner_filled”，则会抑制输入区域内部的空洞。

例程：
* 例程中图像中的边缘被分割成线和圆。
* 对于圆上一部分的边，函数估计圆参数并显示结果圆。
read_image (Image, 'double_circle')
get_image_size (Image, Width, Height)
dev_close_window ()
dev_open_window (0, 0, Width, Height, 'black', WindowHandle)
* 分割包含边缘的区域
fast_threshold (Image, Region, 0, 120, 7)
boundary (Region, RegionBorder, 'inner')
clip_region_rel (RegionBorder, RegionClipped, 5, 5, 5, 5)
dilation_circle (RegionClipped, RegionDilation, 2.5)
reduce_domain (Image, RegionDilation, ImageReduced)
* 在包含边缘的图像的子区域内提取亚像素边缘，并将其打断
edges_sub_pix (ImageReduced, Edges, 'canny', 2, 20, 60)
segment_contours_xld (Edges, ContoursSplit, 'lines_circles', 5, 4, 3)
count_obj (ContoursSplit, Number)
dev_display (Image)
dev_set_draw ('margin')
dev_set_color ('white')
dev_update_window ('off')
for I := 1 to Number by 1
select_obj (ContoursSplit, ObjectSelected, I)
*将适合拟合成圆弧的边缘拟合成圆弧
get_contour_global_attrib_xld (ObjectSelected, 'cont_approx', Attrib)
if (Attrib > 0)
      fit_circle_contour_xld (ObjectSelected, 'ahuber', -1, 2, 0, 3, 2, Row, Column, Radius, StartPhi, EndPhi, PointOrder)
      gen_circle_contour_xld (ContCircle, Row, Column, Radius, 0, rad(360), 'positive', 1.0)
      dev_display (ContCircle)
endif
endfor
dev_set_colored (12)
dev_set_line_width (3)
dev_display (ContoursSplit)

例程将图像进行阈值分割成多个区域，提取区域的边缘。
再将此边缘区域膨胀处理，获取对应图像，
再提取图像的亚像素边缘进行拟合。
这些函数的组合在工业视觉几何测量时经常使用。
[halcon]1[/halcon]

欢迎光临工控编程吧 (https://www.gkbc8.com/)